blob: 7042221df62590ba761e5aa920db3d2990b98cd4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
|
;;; evil-collection-company.el --- Bindings for `company-mode' -*- lexical-binding: t -*-
;; Copyright (C) 2017 James Nguyen
;; Author: James Nguyen <james@jojojames.com>
;; Maintainer: James Nguyen <james@jojojames.com>
;; Pierre Neidhardt <mail@ambrevar.xyz>
;; URL: https://github.com/emacs-evil/evil-collection
;; Version: 0.0.1
;; Package-Requires: ((emacs "26.3"))
;; Keywords: evil, company, abbrev, convenience, matching
;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see <http://www.gnu.org/licenses/>.
;;; Commentary:
;;; Bindings for `company-mode'.
;;; Code:
(require 'company nil t)
(require 'evil-collection)
(declare-function company-tng-mode "company-tng")
(declare-function company-grab-line "company")
(declare-function company-begin-backend "company")
(declare-function company-ensure-emulation-alist "company")
(defgroup evil-collection-company nil
"Evil bindings for `company-mode'."
:group 'evil-collection)
(defcustom evil-collection-company-supported-states '(insert replace emacs)
"The `evil-state's which `company' function can be requested."
:type '(repeat symbol))
(defcustom evil-collection-want-company-extended-keybindings nil
"The \='evil-company-extended' keybindings should be requested"
:type 'boolean)
(defcustom evil-collection-company-enable-keymap-protection t
"Prevent evil from breaking company completion keymap.
When non-nil, prevents evil from overriding `company-active-map'
after calling `company-doc-buffer'. If disabled, the completion
keymap will be in a broken state."
:type 'boolean)
(defvar company-active-map)
(defvar company-search-map)
(defconst evil-collection-company-maps '(company-active-map company-search-map))
(defun evil-collection-company-supported-p (command &rest _)
"Return non-nil if `evil-state' is in supported states."
(cond
((not (bound-and-true-p evil-mode)) t)
((eq command 'prefix)
(memq evil-state evil-collection-company-supported-states))
(t t)))
(defun evil-collection-company-protect-keymap ()
"Prevent evil from overriding `company-mode' completion keymap."
(when (and evil-collection-company-enable-keymap-protection
(memq 'company-emulation-alist emulation-mode-map-alists))
(company-ensure-emulation-alist)))
;;;###autoload
(defun evil-collection-company-whole-lines (command &optional arg &rest _ignored)
"`company-mode' completion backend that completes whole-lines, akin to vim's
C-x C-l."
(interactive (list 'interactive))
(require 'company)
(pcase command
(`interactive (company-begin-backend 'evil-collection-company-whole-lines))
(`prefix (company-grab-line "^[\t\s]*\\(.+\\)" 1))
(`candidates
(all-completions
arg
(delete-dups
(split-string
(replace-regexp-in-string
"^[\t\s]+" ""
(concat (buffer-substring-no-properties (point-min) (line-beginning-position))
(buffer-substring-no-properties (line-end-position) (point-max))))
"\\(\r\n\\|[\n\r]\\)" t))))))
;;;###autoload
(defun evil-collection-company-setup ()
"Set up `evil' bindings for `company'."
(evil-collection-define-key nil 'company-active-map
(kbd "C-n") 'company-select-next-or-abort
(kbd "C-p") 'company-select-previous-or-abort
(kbd "C-j") 'company-select-next-or-abort
(kbd "C-k") 'company-select-previous-or-abort
(kbd "M-j") 'company-select-next
(kbd "M-k") 'company-select-previous)
(when evil-collection-want-company-extended-keybindings
(evil-collection-define-key nil 'company-active-map
(kbd "C-l") 'evil-collection-company-whole-lines
(kbd "C-]") 'company-etags
(kbd "C-f") 'company-files
(kbd "C-o") 'company-capf
(kbd "C-s") 'company-ispell))
(when evil-want-C-u-scroll
(evil-collection-define-key nil 'company-active-map
(kbd "C-u") 'company-previous-page))
(when evil-want-C-d-scroll
(evil-collection-define-key nil 'company-active-map
(kbd "C-d") 'company-next-page))
(evil-collection-define-key nil 'company-search-map
(kbd "C-j") 'company-select-next-or-abort
(kbd "C-k") 'company-select-previous-or-abort
(kbd "M-j") 'company-select-next
(kbd "M-k") 'company-select-previous
(kbd "<escape>") 'company-search-abort)
;; https://github.com/emacs-evil/evil-collection/issues/664
(add-hook 'evil-local-mode-hook #'evil-collection-company-protect-keymap)
;; Make `company-mode' not show popup when not in supported state
(advice-add 'company-call-backend
:before-while 'evil-collection-company-supported-p))
(provide 'evil-collection-company)
;;; evil-collection-company.el ends here
|
